Búsqueda y referencia
BUSCARV en Excel:qué es, cómo se usa y por qué da #N/A
BUSCARV busca un valor en la primera columna de una tabla y devuelve un dato de la misma fila. En inglés se llama VLOOKUP. Sintaxis: =BUSCARV(valor_buscado; matriz_buscar_en; indicador_columnas; [ordenado]).
Sintaxis
=BUSCARV(valor_buscado; matriz_buscar_en; indicador_columnas; [ordenado])En Excel en español los argumentos se separan con punto y coma (;). En México, Perú y otros países con punto decimal, Excel usa coma (,).
Argumentos
| Argumento | Qué es |
|---|---|
valor_buscado | Obligatorio. Lo que buscas, casi siempre una celda con un código. Ejemplo: F2. |
matriz_buscar_en | Obligatorio. La tabla donde buscas. El valor buscado tiene que estar en su primera columna. Ejemplo: $A$2:$D$6. |
indicador_columnas | Obligatorio. Qué columna de esa tabla devuelves, contando desde 1 (la primera de la tabla, no la A de la hoja). Ejemplo: 4. |
ordenado | Opcional, pero ponlo siempre. FALSO (o 0) busca el valor exacto. VERDADERO busca por tramos en una tabla ordenada. Si lo dejas vacío, Excel usa VERDADERO. |
¿Cómo se usa BUSCARV? Ejemplo paso a paso
BUSCARV trae un dato de una tabla a partir de un código. En este ejemplo tienes el catálogo de una papelería en A1:D6 y quieres el precio del código que escribes en F2.
| A | B | C | D | F | ||
|---|---|---|---|---|---|---|
| 1 | Código | Producto | Categoría | Precio | Buscar | |
| 2 | P-101 | Grapadora que nadie devuelve | Oficina | 4,95 | P-103 | |
| 3 | P-102 | Cuaderno A5 | Papelería | 2,30 | ||
| 4 | P-103 | Rotuladores (12 colores) | Papelería | 6,80 | ||
| 5 | P-104 | Silla de oficina | Mobiliario | 89,00 | ||
| 6 | P-105 | Lámpara de escritorio | Mobiliario | 24,50 |
La fórmula es =BUSCARV(F2;A2:D6;4;FALSO) y devuelve 6,8, el precio de los rotuladores.
F2es lo que buscas: el código P-103.A2:D6es la tabla. Empieza en la columna A porque ahí están los códigos.4es la columna que quieres traer: Precio es la cuarta columna de la tabla.FALSOpide el código exacto. Sin él, BUSCARV puede traer el precio de otro producto.
Si cambias el 4 por un 2, =BUSCARV(F2;A2:D6;2;FALSO) devuelve Rotuladores (12 colores). Para usarla en un pedido de 30 líneas, fija la tabla con $ antes de arrastrar: $A$2:$D$6.
¿FALSO o VERDADERO en el último argumento?
FALSO casi siempre. Pide una coincidencia exacta: si el código no está, da #N/A en lugar de inventarse un dato.
VERDADERO sirve para buscar por tramos, como una tabla de comisiones. La primera columna tiene que estar ordenada de menor a mayor:
| H | I | |
|---|---|---|
| 1 | Desde | Comisión |
| 2 | 0 | 0 % |
| 3 | 1000 | 2 % |
| 4 | 5000 | 5 % |
| 5 | 10000 | 8 % |
=BUSCARV(7200;H2:I5;2;VERDADERO) devuelve 0,05 (5 %): busca el tramo más alto que no pasa de 7200, que es el de 5000. Con 800 ventas devuelve 0, y con 12 500 devuelve 0,08.
¿BUSCARV o BUSCARX?
Usa BUSCARX si tu Excel la tiene. Si tienes Excel 2019 o anterior, o la prueba es en un equipo que no sabes qué versión tiene, BUSCARV.
| BUSCARV | BUSCARX | |
|---|---|---|
| Versiones | Todas | Microsoft 365, Excel 2021 y posteriores, Excel para la web |
| Buscar hacia la izquierda | No | Sí |
| Si no encuentra el valor | #N/A (necesitas SI.ERROR) | Tiene un argumento para el aviso |
| Coincidencia por defecto | Aproximada, si omites el último argumento | Exacta |
| Cómo eliges qué devolver | Un número de columna: si insertas una columna en la tabla, el número ya no apunta a la misma | Un rango: se ajusta solo |
La misma búsqueda con BUSCARX es =BUSCARX(F2;A2:A6;D2:D6) y devuelve 6,8. Para buscar hacia la izquierda en un Excel sin BUSCARX, usa INDICE y COINCIDIR.
¿Cómo sale BUSCARV en una prueba de Excel?
En una entrevista de trabajo te dan un pedido con códigos en la columna A y el catálogo en otra pestaña: "Trae el precio de cada línea". La respuesta que esperan es =BUSCARV(A2;Catalogo!$A$2:$D$200;4;FALSO), arrastrada hasta la última línea. Lo que miran: que pongas FALSO y que fijes la tabla con $.
En un test de oposiciones (auxiliar administrativo, por ejemplo) la pregunta suele ser teórica:
¿Qué devuelve
=BUSCARV("P-999";A2:D6;4;FALSO)si P-999 no está en A2:A6? a) 0 · b) #N/A · c) #¡REF! · d) Una celda vacía
Respuesta: b. Con FALSO, si el valor no existe, BUSCARV da #N/A.
Practica BUSCARV
En Busca el precio de un producto escribes esta fórmula en una hoja real y Formulo te dice al momento si está bien y, si no, por qué. Después, Completa todo el pedido te pide arrastrarla con la tabla fijada.
Disponible en: todas las versiones de Excel, en Windows, Mac y Excel para la web. Fuente: Microsoft: función BUSCARV. Resultados calculados con el motor de Formulo y comprobados en Excel.
Errores habituales
- #N/A: el valor no está en la tabla
- Si F2 contiene P-999 y ese código no existe, =BUSCARV(F2;A2:D6;4;FALSO) da #N/A. Comprueba el código o muestra un aviso con SI.ERROR: =SI.ERROR(BUSCARV(F2;A2:D6;4;FALSO);"No existe") devuelve No existe.
- #N/A con un código que ves en la tabla
- Casi siempre es un espacio al final ("P-103 ") o un número guardado como texto. Para Excel, "P-103 " y "P-103" son valores distintos. Quita el espacio con ESPACIOS: =BUSCARV(ESPACIOS(F2);A2:D6;4;FALSO) vuelve a dar 6,8. Si es un número guardado como texto, conviértelo en número con Datos > Texto en columnas.
- #N/A porque la tabla empieza en otra columna
- =BUSCARV(F2;B2:D6;3;FALSO) da #N/A: la tabla empieza en B, así que BUSCARV busca el código entre los nombres de producto. El rango tiene que empezar en la columna del valor buscado.
- #¡REF!: pides una columna que no existe
- La tabla A2:D6 tiene 4 columnas. =BUSCARV(F2;A2:D6;5;FALSO) pide la quinta y da #¡REF!. Amplía el rango o baja el número.
- #¡VALOR!: el número de columna es 0
- indicador_columnas empieza en 1. =BUSCARV(F2;A2:D6;0;FALSO) da #¡VALOR!.
- Trae un dato de otra fila sin dar error
- Falta FALSO al final. Sin él, BUSCARV hace una búsqueda aproximada y, si la tabla no está ordenada, devuelve un dato equivocado sin avisar. Es el error más peligroso porque no se ve.
- Funciona en la primera fila, pero no al arrastrar
- Al copiar la fórmula hacia abajo, A2:D6 pasa a ser A3:D7 y la tabla se mueve. Fíjala con $: $A$2:$D$6.
Preguntas frecuentes
¿Cómo se llama BUSCARV en inglés?
VLOOKUP. Los argumentos son los mismos, pero en un Excel en inglés se separan con coma: =VLOOKUP(F2,A2:D6,4,FALSE).
¿BUSCARV puede buscar hacia la izquierda?
No. Solo devuelve columnas a la derecha de la primera. Para buscar hacia la izquierda usa BUSCARX o INDICE con COINCIDIR.
¿Es lo mismo poner FALSO que 0?
Sí. =BUSCARV(F2;A2:D6;4;0) y =BUSCARV(F2;A2:D6;4;FALSO) devuelven lo mismo: 6,8 en el ejemplo de esta página.
¿BUSCARV distingue mayúsculas y minúsculas?
No. =BUSCARV("p-103";A2:D6;4;FALSO) encuentra P-103 y devuelve 6,8.
¿Qué devuelve BUSCARV si el código está repetido?
El dato de la primera fila en la que aparece. Si necesitas el último, usa BUSCARX con el modo de búsqueda -1.
¿Cómo uso BUSCARV con una tabla que está en otra hoja?
Escribe el nombre de la hoja antes del rango: =BUSCARV(A2;Catalogo!$A$2:$D$200;4;FALSO). Si el nombre de la hoja tiene espacios, va entre comillas simples: 'Lista de precios'!$A$2:$D$200.
¿Cómo quito el #N/A de BUSCARV?
Envuelve la fórmula en SI.ERROR y di qué mostrar: =SI.ERROR(BUSCARV(F2;A2:D6;4;FALSO);"No existe"). Antes, comprueba que el #N/A no es un espacio de más.
Funciones relacionadas
Practica en una hoja de verdad
Ejercicios con datos reales y corrección al momento. Los tres primeros son gratis.